|  |  |  |
| --- | --- | --- |
| # | Expression | Predict |
| 1 | <program> → <global> Lead : Start <body> End . <taskdef> | Let, Var, Task, Array, Object, Lead |
| 2 | <global> → <global\_choice> . <global> | Let, Var, Task, Array, Object |
| 3 | <global> → λ | Lead |
| 4 | <global\_choice> → <varlet> | Let, Var |
| 5 | <global\_choice> → <array> | Array |
| 6 | <global\_choice> → <task> | Task |
| 7 | <global\_choice> → <object> | Object |
| 8 | <dtype> → Int | Int |
| 9 | <dtype> → Double | Double |
| 10 | <dtype> → Char | Char |
| 11 | <dtype> → String | String |
| 12 | <dtype> → Boolean | Boolean |
| 13 | <object> → Object id Start Var <dtype> id. <objdec\_choice> End <varname> | Object |
| 14 | <objdec\_choice> → <objvar> . <objdec\_choice> | Object |
| 15 | <objdec\_choice> → <var> . <objdec\_choice> | Var |
| 16 | <objdec\_choice> → λ | End |
| 17 | <var> → Var <dtype> id | Var |
| 18 | <objvar> → Object id id | Object |
| 19 | <varname> → id <varnames> | id |
| 20 | <varname> → λ | . |
| 21 | <varnames> → ; <varname> | ; |
| 22 | <varnames> → λ | . |
| 23 | <task> → Task <return> id <tparam> | Task |
| 24 | <return> → Null | Null |
| 25 | <return> → <dtype> | Int, Double, Char, String, Boolean |
| 26 | <tparam> → ( Var <dtype> id <tparams> ) | ( |
| 27 | <tparam> → λ | . |
| 28 | <tparams> → ; Var <dtype> id <tparams> | ; |
| 29 | <tparams> → λ | ) |
| 30 | <array> → Array <dtype> id of <size> | Array |
| 31 | <size> → intlit <sizes> | intlit |
| 32 | <sizes> → by intlit | by |
| 33 | <sizes> → λ | . |
| 34 | <varlet> → Let <vardec> | Let |
| 35 | <varlet> → Var <vardec> | Var |
| 36 | <vardec> → <varINT> | Int |
| 37 | <vardec> → <varDOUBLE> | Double |
| 38 | <vardec> → <varCHAR> | Char |
| 39 | <vardec> → <varSTRING> | String |
| 40 | <vardec> → <varBOOLEAN> | Boolean |
| 41 | <varINT> → Int id <initINT> | Int |
| 42 | <initINT> → is <value1> <ids1> | is |
| 43 | <initINT> → λ | . |
| 44 | <varDOUBLE> → Double id <initDOUBLE> | Double |
| 45 | <initDOUBLE> → is <value2> <ids2> | is |
| 46 | <initDOUBLE> → λ | . |
| 47 | <varCHAR> → Char id <initCHAR> | Char |
| 48 | <initCHAR> → is <value3> <ids3> | is |
| 49 | <initCHAR> → λ | . |
| 50 | <varSTRING> → String id <initSTRING> | String |
| 51 | <initSTRING> → is <value4> <ids4> | is |
| 52 | <initSTRING> → λ | . |
| 53 | <varBOOLEAN> → Boolean id <initBOOLEAN> | Boolean |
| 54 | <initBOOLEAN> → is <value5> <ids5> | is |
| 55 | <initBOOLEAN> → λ | . |
| 56 | <ids1> → ; id <value1> <ids1> | ; |
| 57 | <ids1> → λ | . |
| 58 | <ids2> → ; id <value2> <ids2> | ; |
| 59 | <ids2> → λ | . |
| 60 | <ids3> → ; id <value3> <ids3> | ; |
| 61 | <ids3> → λ | . |
| 62 | <ids4> → ; id <value4> <ids4> | ; |
| 63 | <ids4> → λ | . |
| 64 | <ids5> → ; id <value5> <ids5> | ; |
| 65 | <ids5> → λ | . |
| 66 | <value1> → <numvalue> <Operations1> | intlit, id, ++, -- |
| 67 | <value1> → ( <value1> ) <Op1> | ( |
| 68 | <value2> → <doublevalue> <Operations2> | doublelit, id, ++, -- |
| 69 | <value2> → ( <value2> ) <Op2> | ( |
| 70 | <value3> → charlit | charlit |
| 71 | <value4> → stringlit | stringlit |
| 72 | <value5> → boollit | boollit |
| 73 | <numvalue> → intlit | intlit |
| 74 | <numvalue> → <incdecvar> | id, ++, -- |
| 75 | <numvalue> → <objelement> | ++, --, id |
| 76 | <Operations1> → <mathOp> <value1> | +, -, \*, /, % |
| 77 | <Operations1> → λ | ), ;, . |
| 78 | <Op1> → <Operations1> | +, -, \*, /, % |
| 79 | <Op1> → <mathOp> ( <value1> ) | +, -, \*, /, % |
| 80 | <Op1> → λ | ), ;, . |
| 81 | <doublevalue> → doublelit | doublelit |
| 82 | <doublevalue> → <incdecvar> | id, ++, -- |
| 83 | <doublevalue> → <objelement> | ++, --, id |
| 84 | <Operations2> → <mathOp> <value2> | +, -, \*, /, % |
| 85 | <Operations2> → λ | ), ;, . |
| 86 | <Op2> → <Operations2> | +, -, \*, /, % |
| 87 | <Op2> → <mathOp> ( <value2> ) | +, -, \*, /, % |
| 88 | <Op2> → λ | ), ;, . |
| 89 | <mathOp> → + | + |
| 90 | <mathOp> → - | - |
| 91 | <mathOp> → \* | \* |
| 92 | <mathOp> → / | / |
| 93 | <mathOp> → % | % |
| 94 | <incdec> → ++ | ++ |
| 95 | <incdec> → -- | -- |
| 96 | <relop1> → == | == |
| 97 | <relop1> → != | != |
| 98 | <relop1> → > | > |
| 99 | <relop1> → < | < |
| 100 | <relop1> → >= | >= |
| 101 | <relop1> → <= | <= |
| 102 | <logop1> → && | && |
| 103 | <logop1> → || | || |
| 104 | <logop2> → ! | ! |
| 105 | <logop2> → λ | boollit, id, ( |
| 106 | <body> → <statements> | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For |
| 107 | <statements> → <functions> . <statements> | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For |
| 108 | <statements> → λ | Stop, ., End |
| 109 | <functions> → Var <vardec> | Var |
| 110 | <functions> → <varinit> | Int, Char, Boolean, Double, String |
| 111 | <functions> → <incdecvar> | id, ++, -- |
| 112 | <functions> → <array> | Array |
| 113 | <functions> → Clear | Clear |
| 114 | <functions> → <arrayinit> | id |
| 115 | <functions> → <io\_statement> | Read, Say |
| 116 | <functions> → <taskvar> | id |
| 117 | <functions> → <objvar> | Object |
| 118 | <functions> → <objinit> | id |
| 119 | <functions> → <IfOtherwise> | If |
| 120 | <functions> → <loopstate> | Until, Do, For |
| 121 | <functions> → <option> | Option |
| 122 | <varinit> → <varinitINT> | Int |
| 123 | <varinit> → <varinitDOUBLE> | Double |
| 124 | <varinit> → <varinitCHAR> | Char |
| 125 | <varinit> → <varinitSTRING> | String |
| 126 | <varinit> → <varinitBOOLEAN> | Boolean |
| 127 | <varinitINT> → Int id = <INT> | Int |
| 128 | <varinitDOUBLE> → Double id = <DOUBLE> | Double |
| 129 | <varinitCHAR> → Char id = <CHAR> | Char |
| 130 | <varinitSTRING> → String id = <STRING> | String |
| 131 | <varinitBOOLEAN> → Boolean id = <BOOLEAN> | Boolean |
| 132 | <INT> → <value1> | (, intlit, id, ++, -- |
| 133 | <INT> → <task\_id> | id |
| 134 | <DOUBLE> → <value2> | (, doublelit, id, ++, -- |
| 135 | <DOUBLE> → <task\_id> | id |
| 136 | <CHAR> → <value3> | charlit |
| 137 | <CHAR> → <task\_id> | id |
| 138 | <STRING> → <value4> | stringlit |
| 139 | <STRING> → <task\_id> | id |
| 140 | <BOOLEAN> → <value5> | boollit |
| 141 | <BOOLEAN> → <task\_id> | id |
| 142 | <task\_id> → id ( <param> ) | id |
| 143 | <taskvar> → <task\_id> | id |
| 144 | <param> → <value> <params> | intlit, doublelit, charlit, stringlit, boollit, id |
| 145 | <param> → λ | ) |
| 146 | <params> → ; <param> | ; |
| 147 | <params> → λ | ) |
| 148 | <value> → intlit | intlit |
| 149 | <value> → doublelit | doublelit |
| 150 | <value> → charlit | charlit |
| 151 | <value> → stringlit | stringlit |
| 152 | <value> → boollit | boollit |
| 153 | <value> → <input\_id> | id |
| 154 | <io\_statement> → <input> | Read |
| 155 | <io\_statement> → <output> | Say |
| 156 | <input> → Read id | Read |
| 157 | <output> → Say <input\_statement> | Say |
| 158 | <input\_statement> → stringlit <concat> | stringlit |
| 159 | <input\_statement> → <input\_id> <concat> | id |
| 160 | <concat> → , <concat\_value> <concat> | , |
| 161 | <concat> → λ | . |
| 162 | <concat\_value> → stringlit | stringlit |
| 163 | <concat\_value> → <input\_id> | id |
| 164 | <incdecvar> → <incdec> id | ++, -- |
| 165 | <incdecvar> → id <incdec> | id |
| 166 | <objinit> → <element> = <value> | id |
| 167 | <objelement> → <incdec> <element> | ++, -- |
| 168 | <objelement> → <element> <incdec> | id |
| 169 | <element> → id @ id <subelement> | id |
| 170 | <subelement> → @ id <subelement> | @ |
| 171 | <subelement> → λ | Start, ,, ++, --, =, +, -, \*, /, %, ), ;, ., &&, ||, >=, <=, <, >, ==, != |
| 172 | <input\_id> → id <subelement> | id |
| 173 | <arrayinit> → id <index> <multi> = <value> | id |
| 174 | <multi> → <index> | intlit, id |
| 175 | <multi> → λ | = |
| 176 | <index> → intlit | intlit |
| 177 | <index> → id | id |
| 178 | <index> → λ | intlit, id, = |
| 179 | <IfOtherwise> → If ( <conditions> ) <cond\_loop> <or> <otherwise> EndIf | If |
| 180 | <or> → Or ( <conditions> ) <cond\_loop> <or> | Or |
| 181 | <or> → λ | id, !, boollit, (, Otherwise |
| 182 | <otherwise> → Otherwise <cond\_loop> <control> | Otherwise |
| 183 | <otherwise> → λ | EndIf |
| 184 | <cond\_loop> → <functions> . <control> <cond\_loop> | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For |
| 185 | <cond\_loop> → λ | Loop, LoopIf, Skip, Stop, Or, id, !, boollit, (, ), EndIf, Otherwise |
| 186 | <control> → Skip . | Skip |
| 187 | <control> → Stop . | Stop |
| 188 | <control> → λ | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For, Loop, LoopIf, Skip, Stop, Or, !, boollit, (, ), EndIf, Otherwise |
| 189 | <conditions> → <ids> <condsTail> | id, !, boollit |
| 190 | <conditions> → <logop2> <multiconds> | !, ( |
| 191 | <multiconds> → ( <conditions> ) <condsTail> | ( |
| 192 | <ids> → <input\_id> | id |
| 193 | <ids> → <logop2> <ids\_null> | !, boollit, id |
| 194 | <ids\_null> → <value5> | boollit |
| 195 | <ids\_null> → <task\_id> | id |
| 196 | <condsTail> → <logOps> | &&, || |
| 197 | <condsTail> → <relOps> | >=, <=, <, >, ==, != |
| 198 | <condsTail> → λ | ) |
| 199 | <logOps> → <logop1> <conditions> | &&, || |
| 200 | <logOps> → λ | ) |
| 201 | <relOps> → <relopNum> <numval> | >=, <=, <, > |
| 202 | <relOps> → <relopText> <value> | ==, != |
| 203 | <relopNum> → >= | >= |
| 204 | <relopNum> → <= | <= |
| 205 | <relopNum> → < | < |
| 206 | <relopNum> → > | > |
| 207 | <relopText> → == | == |
| 208 | <relopText> → != | != |
| 209 | <numval> → intlit | intlit |
| 210 | <numval> → doublelit | doublelit |
| 211 | <option> → Option <input\_id> Start State <optiontails> | Option |
| 212 | <optiontails> → <optiontail1> | intlit |
| 213 | <optiontails> → <optiontail2> | charlit |
| 214 | <optiontails> → <optiontail3> | stringlit |
| 215 | <optiontail1> → intlit : <statements> Stop . <state1> <default> End | intlit |
| 216 | <optiontail2> → charlit : <statements> Stop . <state2> <default> End | charlit |
| 217 | <optiontail3> → stringlit : <statements> Stop . <state3> <default> End | stringlit |
| 218 | <state1> → State intlit : <statements> Stop . <state1> | State |
| 219 | <state1> → λ | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For, Default |
| 220 | <state2> → State charlit : <statements> Stop . <state2> | State |
| 221 | <state2> → λ | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For, Default |
| 222 | <state3> → State stringlit : <statements> Stop . <state3> | State |
| 223 | <state3> → λ | Var, Clear, Int, Char, Boolean, Double, String, Array, Read, Say, Object, If, Option, id, ++, --, Until, Do, For, Default |
| 224 | <default> → Default : <statements> | Default |
| 225 | <default> → λ | End |
| 226 | <loopstate> → Until ( <conditions> ) <cond\_loop> Loop | Until |
| 227 | <loopstate> → Do <cond\_loop> LoopIf ( <conditions> ) | Do |
| 228 | <loopstate> → For ( <initialize> ; <cond> ; <incdecloop> ) <cond\_loop> Loop | For |
| 229 | <initialize> → id = intlit | id |
| 230 | <initialize> → λ | ; |
| 231 | <cond> → id <relop1> intlit | id |
| 232 | <cond> → λ | ; |
| 233 | <incdecloop> → <incdecvar> | id, ++, -- |
| 234 | <incdecloop> → λ | ) |
| 235 | <taskdef> → Task <returntype> End . <taskdef> | Task |
| 236 | <taskdef> → λ | # |
| 237 | <returntype> → Int id : <taskbody> . Response <returnINT> . | Int |
| 238 | <returntype> → Double id : <taskbody> . Response <returnDOUBLE> . | Double |
| 239 | <returntype> → Char id : <taskbody> . Response <returnCHAR> . | Char |
| 240 | <returntype> → String id : <taskbody> . Response <returnSTRING> . | String |
| 241 | <returntype> → Boolean id : <taskbody> . Response <returnBOOLEAN> . | Boolean |
| 242 | <returntype> → Null id : <taskbody> . | Null |
| 243 | <taskbody> → Start <statements> | Start |
| 244 | <returnINT> → intlit | intlit |
| 245 | <returnINT> → id <returntail> | id |
| 246 | <returnDOUBLE> → doublelit | doublelit |
| 247 | <returnDOUBLE> → id <returntail> | id |
| 248 | <returnCHAR> → charlit | charlit |
| 249 | <returnCHAR> → id <returntail> | id |
| 250 | <returnSTRING> → stringlit | stringlit |
| 251 | <returnSTRING> → id <returntail> | id |
| 252 | <returnBOOLEAN> → boollit | boollit |
| 253 | <returnBOOLEAN> → id <returntail> | id |
| 254 | <returntail> → ( <param> ) | ( |
| 255 | <returntail> → <subelement> | @ |
| 256 | <returntail> → λ | . |
| 257 | <StartProgram> → <program> # | Lead, Let, Var, Task, Array, Object |